#!/bin/csh -f
#
# Convert Hyperlatex documents to dvi, html, or gif's
#
setenv HYPERLATEX_DIR "/usr/local/lib/hyperlatex"
#

if ($#argv < 1) then
 echo "usage: hyperlatex [ -html | -dvi | -gif ] file"
 exit(1)
endif

set run_latex = 0

switch ( $argv[1] )
case "-html" :
  shift
  breaksw
case "-dvi" :
  set run_latex = 1
  set latex_flag = ""
  set make_gifs = 0
  shift
  breaksw
case "-gif" :
  set run_latex = 1
  set latex_flag = "\def\makegifs{}"
  set make_gifs = 1
  shift
  breaksw
endsw

if ($#argv < 1) then
  echo "hyperlatex: no file specified"
  exit(2)
endif

if ($argv[1]:e == tex) then
  set name = $argv[1]
else
  set name = $argv[1].tex
endif

if (! -e $name ) then
  echo "hyperlatex: Cannot find file "\"$name\"
  exit(2)
endif

if ( $run_latex ) then

  latex "$latex_flag\input{$name}"
  if ( ! $status && $make_gifs ) then
    /bin/csh $name:r.makegif
  endif

else

  emacs -batch -no-init-file -no-site-file \
    -l $HYPERLATEX_DIR/hyperlatex.elc -funcall batch-hyperlatex-format \
    $name

endif
