!set n=$teller
!if $BEREKENINGEN=1
    bewerking=bewerking4.proc
!else
    bewerking=bewerking1.proc
!endif    
max_aantal=6
min_aantal=2
!if $graad =0
    R=$teller
!else
    R=$graad
!endif        

!if $variabelen=1
    X$n=!randitem a,b,c,d,f,x,y,z,p,g,k,t,r,n,m
!else
    X$n=x
!endif

gg=!randint 2,25
pm=!randitem -1,1
G$n=$[$pm*$gg]

!if $breuken=0
    !if $taal=nl
	nivo_title=Los de volgende vergelijking op (alle bewerkingen)
    !else
	nivo_title=Solve the equation
    !endif
    a=!randitem 2,3,4,5,6,7,8,9,10,11,12,13,14
            
    !if $R=1 	
	b=$[$(G$n)+$a]
	som$n=$a + $(X$n) \,\,\,=\,\,\,$b 
	extra$n=$a + $(X$n) - $a\,\,\,=\,\,\,$b - $a \Longrightarrow $(X$n) \,\,=\,\, $b - $a \Longrightarrow $(X$n) \,\,=\,\, $(G$n)
     !exit	
    !endif
	
    !if $R=2 
	b=$[$a - $(G$n)]
	som$n=$a - $(X$n) \,\,\,=\,\,\,$b 
	extra$n=$a - $(X$n) - $a\,\,\,=\,\,\,$b - $a \Longrightarrow - $(X$n) \,\,=\,\, $b - $a \Longrightarrow $(X$n) \,\,=\,\, $(G$n)
     !exit	
    !endif
	
    !if $R=3 
	b=$[$(G$n)*$a]
	som$n=$a \cdot $(X$n) \,\,\,=\,\,\,$b 
	extra$n=\frac{\left($a \cdot $(X$n) \right)}{$a} \,\,\,=\,\,\, \frac{$b}{$a} \Longrightarrow $(X$n) \,\,=\,\, $(G$n)
     !exit	
    !endif
	
    !if $R>3 
	b=!randitem 2,3,4,5,6,7,8
	G$n=$[$b*$a]
	som$n=\frac{$(X$n)}{$a} \,\,\,=\,\,\, $b
	extra$n=\frac{$a \cdot $(X$n)}{$a} \,\,\,=\,\,\, $a \cdot $b \Longrightarrow $(X$n) \,\,=\,\, $(G$n) 
     !exit	
    !endif
!else
    !if $taal=nl
	nivo_title=Los de volgende vergelijking op (alle bewerkingen)<br>Met Breuken 
    !else
	nivo_title=Solve the equation
    !endif
	
    a=!randitem 1/2,1/3,1/4,1/5,1/6,1/7,1/8,1/9,1/10,2/3,3/4,2/5,3/5,5/6,2/7,3/7,4/7,5/7,6/7,3/8,5/8,7/8,2/9,5/9,7/9,8/9,3/10,7/10,9/10	
    aa=!replace internal / by , in $a
    a1=!item 1 of $aa
    a2=!item 2 of $aa
    A=\frac{$a1}{$a2}

    !if $R=1 	
	bb=!exec pari A=$(G$n)+$a\
	printtex(A)
	b=!line 1 of $bb
	B=!line 2 of $bb
	som$n=$A + $(X$n) \,\,\,=\,\,\,$B 
	extra$n=$A + $(X$n) - $A\,\,\,=\,\,\,$B - $A \Longrightarrow $(X$n) \,\,=\,\, $B - $A \Longrightarrow $(X$n) \,\,=\,\, $(G$n)
     !exit	
    !endif

    !if $R=2 
	bb=!exec pari A=$a - $(G$n)\
	printtex(A)
	b=!line 1 of $bb
	B=!line 2 of $bb
	som$n=$A - $(X$n) \,\,\,=\,\,\,$B 
	extra$n=$A - $(X$n) + $(X$n)\,\,\,=\,\,\,$B + $(X$n) \Longrightarrow $(X$n) \,\,=\,\, $A - $B \Longrightarrow $(X$n) \,\,=\,\, $(G$n)
     !exit	
    !endif
	
    !if $R=3 
	bb=!exec pari A=$(G$n)*$a\
	printtex(A)
	b=!line 1 of $bb
	B=!line 2 of $bb
	som$n=$A \cdot $(X$n) \,\,\,=\,\,\,$B 
	extra$n=$(X$n)  \,\,\,=\,\,\, \frac{$B}{$A} \Longrightarrow $(X$n) \,\,=\,\, $(G$n)
     !exit	
    !endif
	
    !if $R>3 
	c=!randitem 1,2,3,4,5,6
	d=!randitem 7,8,9,10,11,12,13
	bb=!exec pari A=$c/$d\
	printtex(A)
	b=!line 1 of $bb
	B=!line 2 of $bb
	gg=!exec pari A=$b*$a\
	printtex(A)
	G$n=!line 1 of $gg
	G=!line 2 of $gg
	som$n=\frac{$(X$n)}{$A} \,\,\,=\,\,\, $B
	extra$n=$(X$n) \,\,\,=\,\,\,$A \cdot $B \Longrightarrow $(X$n) \,\,=\,\, $G 
     !exit	
    !endif
!endif

