!set n=$teller
max_aantal=8
min_aantal=2

!if $taal=nl
    nivo_title=Los de volgende vergelijking op.
!else
    nivo_title=Solve the equation.
!endif

!if $BEREKENINGEN = 1
    bewerking=bewerking4.proc
!else
    bewerking=bewerking1.proc
!endif    

!if $graad =0
    R=$teller
!else
    R=$graad
!endif    

!if $variabelen=1
    X$n=!randitem a,b,c,d,f,x,y,z,p,g,k,t,r,n,m
!else
    X$n=x
!endif
!if $breuken=0    	
    a=!randitem 2,3,4,5
    b=!randitem 1,2,3,4
    gg=!randint 2,50
    pm=!randitem -1,1
    G$n=$[$pm*$gg]
    
    !if $R=1 
	# a(x+b)=c => ax+ab=c => ax=c-ab => 	
	c=$[$a*($(G$n) + $b)]	    
	som$n=$a \cdot\left( $(X$n) + $b \right) \,\,\,=\,\,\, $c
	extra$n=$(X$n) + $b = \frac{$c}{$a} \Longrightarrow $(X$n) \,\,=\,\,\frac{$c}{$a} - $b = $(G$n)
     !exit
    !endif
	
    !if $R=2 
	#a(x-b)=c 	
	c=$[$a*($(G$n) - $b)]	    
	som$n=$a \cdot\left( $(X$n) - $b \right) \,\,\,=\,\,\, $c 
	extra$n=$(X$n) - $b = \frac{$c}{$a} \Longrightarrow $(X$n) \,\,=\,\,\frac{$c}{$a} + $b = $(G$n)
     !exit
    !endif
	
    !if $R=3 
	#a(x+b) = c*x => ax+ab = cx => ab=(c-a)x => x=(ab)/(c-a)
	c=!randitem 2,3,4,5,6
	c=$[$a+$c]
	gg=!exec pari A=($a*$b/($c -$a))\
	printtex(A)
	G$n=!line 1 of $gg
	G=!line 2 of $gg	    
	som$n=$a \cdot\left( $(X$n) + $b \right) \,\,\,=\,\,\, $c \cdot $(X$n)
	# a(x+b) = cx => ax +ab = cx =>  ab =(c-a)x => c =ab/(c-a) =G
	extra$n=$a\cdot $(X$n) + $[$a*$b] =  $c \cdot $(X$n) \Longrightarrow $[$a*$b]=$[$c-$a]\cdot $(X$n) \Longrightarrow $(X$n) = \frac{$[$a*$b]}{$[$c-$a]} = $G
     !exit
    !endif
    
    !if $R>3 
	#a(x-b) = c*x => ax-ab = cx => ax-cx = ab => x(a-c)=ab => x= ab/(a-c)
	c=!randitem 2,3,4,5,6
	c=$[$a+$c]
	gg=!exec pari A=($a*$b/($a -$c))\
	printtex(A)
	G$n=!line 1 of $gg
	G=!line 2 of $gg	    
	som$n=$a \cdot\left( $(X$n) - $b \right) \,\,\,=\,\,\, $c \cdot $(X$n) 
	extra$n=$a\cdot $(X$n) -$[$a*$b] = $c\cdot $(X$n)  \Longrightarrow $[$c-$a]\cdot $(X$n)= - $[$a*$b] \Longrightarrow $(X$n) = $G 
     !exit
    !endif
!else
    b=!randitem 1,2,3,4,5,6,7,8,9,10
    gg=!randint 2,50
    pm=!randitem -1,1
    G$n=$[$pm*$gg]
    
    !if $R=1
	a=!randitem 1/2,1/3,1/4,1/5,1/6
	# a(x+b)=c => ax+ab=c => ax=c-ab => x=(c-ab)/a	
	tot=!exec pari A=($a*($(G$n) + $b))\
	printtex(A)\
	printtex($a)
	c=!line 1 of $tot
	C=!line 2 of $tot
	A=!line 3 of $tot	    
	som$n=$A \cdot\left( $(X$n) + $b \right) \,\,\,=\,\,\, $C
	extra$n=\left($(X$n) + $b\right) = $[1/($a)] \cdot $C \Longrightarrow $(X$n) + $b= $[($c)/($a)] \Longrightarrow $(X$n)= $(G$n)
     !exit
    !endif
	
    !if $R=2 
	a=!randitem 1/2,1/3,1/4,1/5,1/6,2/3,3/4,4/5
	#a(x-b)=c  => ax-ab=c => ax=c+ab =>x=(c+ab)/a	
	tot=!exec pari A=($a*($(G$n) - $b))\
	printtex(A)\
	printtex($a)
	c=!line 1 of $tot
	C=!line 2 of $tot
	A=!line 3 of $tot	    
	som$n=$A \cdot\left( $(X$n) - $b \right) \,\,\,=\,\,\, $C
	extra$n=\left($(X$n) - $b\right) = $[1/($a)] \cdot $C \Longrightarrow $(X$n) - $b= $[($c)/($a)] \Longrightarrow $(X$n)= $(G$n)
     !exit
    !endif
	
    !if $R=3 
	G$n=!randitem 2,3,4,5,6,7,8,9,-2,-3,-4,-5,-6,-7,-8,-9
	!if $(G$n) = $[-1*$b]
	    G$n=$b
	!endif    
	a=!randitem 1/2,1/3,1/4,1/5,1/6
	no=!replace internal / by , in $a
	no=!item 2 of $no
	#a(x+b) = c*x => c=a(x+b)/x
	# => no*a(x+b)=no*c*x =>  no*a*x+no*a*b=no*c*x => 
	tot=!exec pari C=$a*($(G$n) + $b)/$(G$n)\
	printtex(C)\
	printtex($a)\
	printtex($no*C)
	
	
	c=!line 1 of $tot
	C=!line 2 of $tot
	A=!line 3 of $tot
	NO=!line 4 of $tot
	som$n=$A \cdot\left( $(X$n) + $b \right) \,\,\,=\,\,\, $C \cdot $(X$n) 
	extra$n=$no \cdot $A \cdot\left( $(X$n) + $b \right)=$no \cdot $C \cdot $(X$n) \Longrightarrow $(X$n) + $b = $NO \cdot $(X$n) \Longrightarrow $(X$n)=$(G$n)
     !exit
    !endif
    
    !if $R>3 
	G$n=!randitem 2,3,4,5,6,7,8,9,-2,-3,-4,-5,-6,-7,-8,-9
	!if $(G$n) = $b
	    G$n=$[-1*$b]
	!endif    
	a=!randitem 1/2,1/3,1/4,1/5,2/5,4/5,3/5,3/4,2/3
	no=!replace internal / by , in $a
	no=!item 2 of $no
	#a(x-b) = c*x => c=a(x-b)/x
	tot=!exec pari C=$a*($(G$n) - $b)/$(G$n)\
	printtex(C)\
	printtex($a)\
	printtex($no*C)
	
	
	c=!line 1 of $tot
	C=!line 2 of $tot
	A=!line 3 of $tot
	NO=!line 4 of $tot
	som$n=$A \cdot\left( $(X$n) - $b \right) \,\,\,=\,\,\, $C \cdot $(X$n) 
	extra$n=$no \cdot $A \cdot\left( $(X$n) - $b \right)=$no \cdot $C \cdot $(X$n) \Longrightarrow $(X$n) - $b = $NO \cdot $(X$n) \Longrightarrow $(X$n)=$(G$n)
     !exit
    !endif
!endif
