!set n=$teller
bewerking=bewerking3.proc
!if $taal=nl
    nivo_title=Los het volgende stelsel van drie vergelijkingen op.
!else
    nivo_title=Solve the set of three equations.
!endif
	
!if $graad =0
    R=$teller
!else
    R=$graad
!endif    
	
!if $variabelen=1
    letters=a,b,c,d,f,x,y,z,p,g,k,t,r,n,m
    letters=!shuffle $letters 
    X$n=!item 1 of $letters
    Y$n=!item 2 of $letters
    Z$n=!item 3 of $letters
!else
    X$n=x
    Y$n=y
    Z$n=z
!endif

!if $breuken=0
    G$n=!randint 2,25
    GG$n=!randint 2,25
    GGG$n=!randint 2,25
    #X => G 
    #Y => GG
    #Z => GGG
    !if $R=1
        #x=a+y
        #y=b+z
        #z=c
        p=!randitem 2,3,4,5,6,7,8
	a=$[$(G$n) - $(GG$n)]
        b=$[$(GG$n) - $(GGG$n)]
        c=$[$p*$(GGG$n)]
        som$n=\left\{ \begin{array}{c}$(X$n) = $a + $(Y$n) \\ \\ $(Y$n) = $b + $(Z$n) \\ \\ $p\cdot $(Z$n) = $c  \end{array}\right. \,\,\, 
        extra$n=\left\{ \begin{array}{c} $(X$n)= $(G$n) \\ \\ $(Y$n) = $(GG$n) \\ \\ $(Z$n) = $(GGG$n) \end{array}\right. \,\,\,
     !exit
    !endif
	
    !if $R=2 
        #x+2y=a
        #y-z=b
        #z=c
        p=!randitem 2,3,4,5,6,7,8,-2,-3,-4,-5,-6,-7,-8 	    
           
	a=$[$(G$n) + 2*$(GG$n)]	
        b=$[$(GG$n) - $(GGG$n)]
        c=\frac{$[2*$(GGG$n)]}{$[2*$p]}
        som$n=\left\{ \begin{array}{c}$(X$n) + 2\cdot $(Y$n) = $a \\ \\ $(Y$n) - $(Z$n) = $b \\ \\ \frac{1}{$p}\cdot $(Z$n) = $c \end{array}\right. \,\,\, 
        extra$n=\left\{ \begin{array}{c} $(X$n)= $(G$n) \\ \\ $(Y$n) = $(GG$n) \\ \\ $(Z$n) = $(GGG$n) \end{array}\right. \,\,\,
     !exit
    !endif
	
    !if $R=3
        p=!randitem 2,3,4,5,6,7,8 
        #x*y=a
        #y*z=b
        #z=c
        a=$[$(G$n)*$(GG$n)]
        b=$[$(GG$n)*$(GGG$n)]
	c=$[$(GGG$n)*$p]
        som$n=\left\{ \begin{array}{c}$(X$n) \cdot $(Y$n) = $a \\ \\ $(Y$n) \cdot $(Z$n) = $b \\ \\ $p\cdot $(Z$n) = $c \end{array}\right. \,\,\, 
	extra$n=\left\{ \begin{array}{c} $(X$n)= $(G$n) \\ \\ $(Y$n) = $(GG$n) \\ \\ $(Z$n) = $(GGG$n) \end{array}\right. \,\,\,
     !exit
    !endif
	
    !if $R>3 
        p=!randitem 2,3,4,5,6,7,8 
        r=!randitem 2,3,4,5,6,7,8
        s=!randitem 2,3,4,5,6,7,8
	!if $r = $[-1*$(GG$n)]
	    r=$[$r+1]
	!endif    
	!if $s = $(GGG$n)
	    s=$[$s+1]
	!endif    
        #x(y+r)=a
	#y(z-s)=b
        #p(z-x)=c
	a=$[$(G$n)*($(GG$n) + $r)]
        b=$[$(GG$n)*($(GGG$n) - $s)]
        c=$[$p*$(GGG$n)]
        som$n=\left\{ \begin{array}{c}$(X$n) \left( $(Y$n) + $r \right) = $a \\ \\ $(Y$n) \left( $(Z$n) - $s \right) = $b \\ \\ $p \cdot $(Z$n) = $c \end{array}\right. \,\,\,
        extra$n=\left\{ \begin{array}{c} $(X$n)= $(G$n) \\ \\ $(Y$n) = $(GG$n) \\ \\ $(Z$n) = $(GGG$n) \end{array}\right. \,\,\,
     !exit
    !endif
!else
    breuk=!shuffle 1/2,1/6,1/4,1/5,2/5,3/2,5/2,1/3,2/3,4/3,3/4,5/4,5/8,3/8,1/8,7/8
    G$n=!item 1 of $breuk
    GG$n=!item 2 of $breuk 
    GGG$n=!item 3 of $breuk
    p=!randitem 2,3,4,5,6,7,8
    #X => G 
    #Y => GG
    #Z => GGG
    !if $R=1
        #x=a+y => a=x-y => a=G-GG
        #y=b+z => b=GG-GGG
        #z=c
	tot=!exec pari printtex($(G$n) - $(GG$n))\
	printtex($(GG$n) - $(GGG$n))\
	printtex($p*($(GGG$n)))
	 	    
        a=!line 1 of $tot
        b=!line 2 of $tot
        c=!line 3 of $tot
        som$n=\left\{ \begin{array}{c}$(X$n) = $a + $(Y$n) \\ \\ $(Y$n) = $b + $(Z$n) \\ \\ $p\cdot $(Z$n) = $c  \end{array}\right. \,\,\, 
        extra$n=\left\{ \begin{array}{c} $(X$n)= $(G$n) \\ \\ $(Y$n) = $(GG$n) \\ \\ $(Z$n) = $(GGG$n) \end{array}\right. \,\,\,
     !exit
    !endif
	
    !if $R=2 
        #x+2y=a
        #y-z=b
        #z=c
	tot=!exec pari printtex($(G$n) + 2*$(GG$n))\
	printtex($(GG$n) - $(GGG$n))\
	printtex(2*$(GGG$n)/(2*$p))
        
	a=!line 1 of $tot
        b=!line 2 of $tot
        c=!line 3 of $tot	
        som$n=\left\{ \begin{array}{c}$(X$n) + 2\cdot $(Y$n) = $a \\ \\ $(Y$n) - $(Z$n) = $b \\ \\ \frac{1}{$p}\cdot $(Z$n) = $c \end{array}\right. \,\,\, 
        extra$n=\left\{ \begin{array}{c} $(X$n)= $(G$n) \\ \\ $(Y$n) = $(GG$n) \\ \\ $(Z$n) = $(GGG$n) \end{array}\right. \,\,\,
     !exit
    !endif
	
    !if $R=3
        #x*y=a
        #y*z=b
        #z=c
	tot=!exec pari printtex($(G$n)*$(GG$n))\
	printtex($(GG$n)*$(GGG$n))\
	printtex(($(GGG$n))*$p)
        
	a=!line 1 of $tot
        b=!line 2 of $tot
        c=!line 3 of $tot
        som$n=\left\{ \begin{array}{c}$(X$n) \cdot $(Y$n) = $a \\ \\ $(Y$n) \cdot $(Z$n) = $b \\ \\ $p\cdot $(Z$n) = $c \end{array}\right. \,\,\, 
	extra$n=\left\{ \begin{array}{c} $(X$n)= $(G$n) \\ \\ $(Y$n) = $(GG$n) \\ \\ $(Z$n) = $(GGG$n) \end{array}\right. \,\,\,
     !exit
    !endif
	
    !if $R>3 
        p=!randitem 2,3,4,5,6,7,8 
        r=!randitem 2,3,4,5,6,7,8
        s=!randitem 2,3,4,5,6,7,8
	!if $r = $[-1*$(GG$n)]
	    r=$[$r+1]
	!endif 
	!if $s = $(GGG$n)
	    s=$[$s+1]
	!endif       
        #x(y+r)=a
	#y(z-s)=b
        #px=c
	tot=!exec pari printtex($(G$n)*($(GG$n) + $r))\
	printtex($(GG$n)*($(GGG$n) - $s))\
	printtex($p*($(GGG$n)))
	a=!line 1 of $tot
        b=!line 2 of $tot
        c=!line 3 of $tot
        som$n=\left\{ \begin{array}{c}$(X$n) \left( $(Y$n) + $r \right) = $a \\ \\ $(Y$n) \left( $(Z$n) - $s \right) = $b \\ \\ $p \cdot $(Z$n) = $c \end{array}\right. \,\,\,
        extra$n=\left\{ \begin{array}{c} $(X$n)= $(G$n) \\ \\ $(Y$n) = $(GG$n) \\ \\ $(Z$n) = $(GGG$n) \end{array}\right. \,\,\,
     !exit
    !endif
!endif

