bewerking=nivo/bewerking2.proc
!set n=$teller
!if $graad=0
    R=$teller
!else
    R=$graad
!endif        
nivo_title=!record 52 of lang/remarks.$taal
somtekst$n=!record 53 of lang/remarks.$taal

plaatje=0
breuk=0
varlist=0
x=!randitem r,x,q
y=!randitem p,y,v
z=!randitem t,z,w
wims_texsize=+2
keuze=0
# nu even niet
!if $R=1
    !if $keuze=0
	wims_rawmath_variables=x
	a=!randitem 2,3,4,5,6,7,8,9,10
	g=!randitem 2,3,4,5,6,7,8,9,10
	opgave$n=$g^{x} = $a
	!if $a=$g
	    log=0
	    GOED$n=1
	    goed$n=x = ^{$g}\log \left( $a \right) = 1
	    !goto KLAAR1
	!endif
	!if $a=10
	    log=1
	    GOED$n=1/log($g)
	    goed$n=x = ^{$g}\log \left( $a \right) = \frac{1}{ \log \left( $g \right) }
	    !goto KLAAR1
	!endif
	!if $g=10
	    log=1
	    GOED$n=log($a)
	    goed$n=x = ^{$g}\log \left( $a \right) = \log \left( $a \right)
	    !goto KLAAR1
	!endif
	
	test=$[log($a)/(log($g))]
	!if . notin $test
	    log=0
	    GOED$n=$test
	    goed$n=x = ^{$g}\log \left( $a \right) = $test
	!else
	    log=2
	    GOED$n=log($a)/log($g)
	    goed$n=x = ^{$g}\log \left( $a \right) = \frac{\log \left( $a \right)}{\log \left( $g \right)}
	!endif
	:KLAAR1
    !else
	log=2
	varlist=1
	wims_rawmath_variables=x,$y,$z
	opgave$n=$z^{x} = $y
	GOED$n=log($y)/log($z)
	goed$n= x = ^{$z}\log \left( $y \right) =  \frac{ \log \left( $y \right) }{ \log \left( $z \right) }
    !endif
 !exit
!endif

!if $R=2
    !if $keuze=0
	wims_rawmath_variables=x
	a=!randitem 2,3,4,5,6,7,8,9,10
	b=!randitem 2,3,4,5,6,7,8,9,10
	g=!randitem 2,3,4,5,6,7,8,9,10
	opgave$n=$g^{$b \cdot x} = $a
	!if $a=$g
	    log=0
	    GOED$n=1/$b
	    goed$n= $b \cdot x = 1 \rightarrow x = \frac{1}{$b}
	    !goto KLAAR2
	!endif
	!if $a=10
	    log=1
	    GOED$n=1/($b*log($g))
	    goed$n= b\cdot x = ^{$g}\log \left( 10 \right) \rightarrow $b\cdot x=\frac{\log \left( 10 \right)}{\log \left( $g \right)}= \frac{1}{\log \left( $g \right)} \rightarrow x = \frac{1}{$b \cdot \log \left( $g \right)}
	    !goto KLAAR2
	!endif
	!if $g=10
	    log=1
	    GOED$n=(log($a))/$b
	    goed$n=b \cdot x =\log \left( $a \right) \rightarrow x = \frac{ \log \left( $a \right)}{$b}
	    !goto KLAAR2
	!endif
	log=2
	GOED$n=log($a)/($b*log($g))
	goed$n=$b \cdot x = ^{$g}\log \left( $a \right) \rightarrow x = \frac{1}{$b} \cdot ^{$g}\log \left( $a \right) =\frac{1}{$b} \cdot \frac{\log\left( $a \right) }{ \log \left( $g \right)} 
	:KLAAR2
    !endif
    !exit
!endif

!if $R>2
    log=0
    wims_rawmath_variables=x
    !if $keuze=0
	pm=+
	mp=-
    !else
	pm=-
	mp=+
    !endif	
    b=!randitem 2,3,4,5
    d=!randitem 1,2,3
    a=!randitem 2,3,4,5,6,7,8,9,10
    g=!randitem 2,3,4,5,6,7,8,9,10
    c=$[$d*$b]
    opgave$n=$g^{$b\cdot x $pm $c} = $a	
    !if $a=$g
	log=0
	GOED$n=1/$b $mp $d	
	goed$n= $b \cdot x $pm $c = 1 \rightarrow x = \frac{1}{$b} $mp \frac{$c}{$c} \rightarrow x= \frac{1}{$b} $mp $d
	!goto KLAAR3
    !endif
    !if $a=10
	log=1
	GOED$n=1/($b*log($g)) $mp $d
	goed$n= $b\cdot x $pm $c  = ^{$g}\log \left( 10 \right) =\frac{\log \left( 10 \right)}{\log \left( $g \right)}= \frac{1}{\log \left( $g \right)} \rightarrow $b\cdot x = \frac{1}{\log \left( $g \right)} $mp $c \rightarrow x = \frac{1}{$b \cdot \log \left( $g \right)} $mp $d
	!goto KLAAR3
    !endif
    !if $g=10
	log=1
	GOED$n=(log($a))/$b $mp $d
	goed$n=b \cdot x $pm $c  =\log \left( $a \right) \rightarrow $b \cdot x = \log \left( $a \right) $mp $c \rightarrow x = \frac{ \log \left( $a \right) }{$b} $mp $d
	!goto KLAAR3
    !endif
    log=2
    GOED$n=(log($a))/($b*log($g)) $mp $d
    goed$n=$b \cdot x $pm $c = ^{$g}\log \left( $a \right) \rightarrow $b \cdot x =  ^{$g}\log \left( $a \right) $mp $c \rightarrow  x = \frac{1}{$b} \cdot ^{$g}\log \left( $a \right) $mp \frac{$c}{$b} \rightarrow x= \frac{ \log \left( $a \right)}{$b \cdot \log \left( $g \right)} $mp $d
    # niet echt elegant...
    :KLAAR3
    !exit
!endif

















