!set n=$teller
kans=1
!if $graad=0
    R=$teller
!else
    R=$graad
!endif  
lijst=!shuffle 1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,\
20,21,22,23,24,25,26,27,28,29,30,31,32,33,34,35,36,37,38,39,\
40,41,42,43,44,45,46,47,48,49,50,51,52

opgave$n=$empty
bewerking=bewerking1.proc
nivo_title=kaartleggen, bereken de kans.
!if $R=1
    nummer=!item 1 of $lijst 	
    index=!record $nummer of cards/index
    naam=!item 3 of $index
    num=!item 2 of $index
    gif=!item 1 of $index
    gif=<img src="$module_dir/cards/$gif"> 
    !if $num > 10
	!if $num=11
	    num=&nbsp;Boer
	    !goto KLAAR
	!endif
	!if $num=12
	    num=&nbsp;Vrouw
	    !goto KLAAR
	!endif
	!if $num=13
    	    num=&nbsp;Heer
	    !goto KLAAR
	!endif
    !endif
    !if $num=1
	num=Aas
    !endif
    :KLAAR
    k=!randint 4,51
    somtekst$n=Ik heb een volledige pakje kaarten.<br>\
    Ik schud ze goed door elkaar en pak vervolgens $[$k+1] kaarten van het stapeltje af<br>\
    en draai er $k om...<br>\
    Hoe groot is nu de kans dat de nog niet omgedraaide kaart een <em>$naam $num</em> is ?<br>$gif
    opgave$n=!append line <img src="$module_dir/cards/0.gif"> to $(opgave$n)
    !for p=2 to $[$k+1]
	# p=1 is gereserveerd voor de showkaart...
	nummer=!item $p of $lijst 	
	index=!record $nummer of cards/index
        gif=!item 1 of $index
        opgave$n=!append line <img src="$module_dir/cards/$gif"> to $(opgave$n)
    !next p    
    GOED$n=$[1/(52-$k)]
    GG=$[(round($afrondingsfactor*$(GOED$n)))/$afrondingsfactor]
    goed$n=De kans op een $naam $num uit een stapeltje kaarten is natuurlijk 1/52<br>\
    Liggen er al $k andere kaarten op tafel -er zijn dus in het spel kaarten nog 52-$k over)<br>\
    is de kans op een bepaalde kaart 1/(52-$k) = 1/$[52-$k] =$(GOED$n) of afgerond $GG .
    tex$n=0
 !exit
!endif

!if $R=2
    type=5
    kaarten=$empty
    extratext=$empty
    som=0
    min=13
    lijst=!shuffle 1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,\
    20,21,22,23,24,25,26,27,28,29,30,31,32,33,34,35,36,37,38,39,\
    40,41,42,43,44,45,46,47,48,49,50,51,52
    !for p=1 to 2	
	nummer=!item $p of $lijst 	
	index=!record $nummer of cards/index
	naam=!item 3 of $index
	num=!item 2 of $index
	som=$[$num + $som]
	gif=!item 1 of $index
	gif=<img src="$module_dir/cards/$gif"> 
	kaarten=!append line $gif to $kaarten	
	opgave$n=!append line <img src="$module_dir/cards/0.gif"> to $(opgave$n)
    !next p
    waarde=$[28-$som]
    !if $waarde<$som
	mogelijkheden=$[$waarde-1]
        #GOED$n=$[($waarde-1)/169]
    !else
	mogelijkheden=$[$som-1]
	#GOED$n=$[($som-1)/169]
    !endif
    test=!exec pari Mod($mogelijkheden,2)
    # test=Mod(0,2) even
    test=!char 5 of $test
    !if $test=0
	# dus even
	GOED$n=$[$mogelijkheden*4/663]
	# $[$mogelijkheden*(1/13)*(4/51)]
	goed$n=Ik heb twee kaarten omgedraaid...<br>\
	Er zijn $mogelijkheden manieren om twee kaarten te pakken waarvan de som $som is...<br>\
	<small><em>zie de tabel in de help-pagina</em></small><br>\
	De kans is dan: $mogelijkheden &times; (4/52) &times; (4/51) = $mogelijkheden &times; 4/663 = $(GOED$n)
    !else
	# dus oneven
	GOED$n=$[($mogelijkheden-1)*4/663 + 1/221]
	# $[($mogelijkheden-1)*(1/13)*(4/51) + 4/52*(3/51) ]
	goed$n=Ik heb twee kaarten omgedraaid...<br>\
	Er zijn $mogelijkheden manieren om twee kaarten te pakken waarvan de som $som is...<br>\
	<small><em>zie de tabel in de help-pagina</em></small><br>\
	Omdat de som van de kaarten ($som) even is,<br>is er &eacute;&eacute;n mogelijkheid waarbij je twee kaarten pakt\
	met de zelfde waarde...<br>\
	De kans is dan: ( $mogelijkheden - 1) &times; (4/52) &times; (4/51) + (4/52)&times;(3/51) = $[$mogelijkheden-1] &times; 4/663 + 1/221 = $(GOED$n)
    !endif	
    somtekst$n=Van een goed geschud pakje kaarten pak ik de eerste twee kaarten.<br>\
    Hoe groot is de kans dat de waarde van twee omgedraaide kaarten samen $som is?\
    <br><small>Let op: De waarde van een Boer=11 ; een Vrouw=12 ; een Koning=13 en een Aas=1</small><br>\
    <br>Zoals <em>bijvoorbeeld</em> in deze combinatie:<br>$kaarten
    tex$n=0
 !exit
!endif

!if $R>2
    !if $R=3
	opkop=2
	k=!randint 3,42
    !else
	opkop=!randitem 3,4,5,6
	k=!randint 25,52
    !endif	
    type=5
    kaarten=$empty
    !for p=1 to $opkop	
	nummer=!item $p of $lijst 	
	index=!record $nummer of cards/index
	naam=!item 3 of $index
	num=!item 2 of $index
	gif=!item 1 of $index
	!if $num > 10
	    !if $num=11
		num=&nbsp;Boer
	    !endif
    	    !if $num=12
		num=&nbsp;Vrouw
	    !endif
	    !if $num=13
    		num=&nbsp;Heer
	    !endif
	!endif
	!if $num=1
	    num=Aas
	!endif
	NAAM=!append line $naam $num ; to $NAAM
	gif=<img src="$module_dir/cards/$gif"> 
	kaarten=!append line $gif to $kaarten	
	opgave$n=!append line <img src="$module_dir/cards/0.gif"> to $(opgave$n)
    !next p
    somtekst$n=Ik leg $k kaarten op tafel. Ik draai er $[$k - $opkop] om.<br>\
    Hoe groot is de kans dat de nog niet omgedraaide $opkop kaarten de volgende combinatie heeft?<br><small>$NAAM</small><br>\
    <small>de volgorde van deze $opkop kaarten doet er niet toe</small><br>$kaarten
    !for p=$[$opkop+1] to $k
	# p=1 is gereserveerd voor de showkaart...
	nummer=!item $p of $lijst 	
	index=!record $nummer of cards/index
        gif=!item 1 of $index
        opgave$n=!append line <img src="$module_dir/cards/$gif"> to $(opgave$n)
    !next p    
    over=$[52 - $k + $opkop]
    term=1
    extratext=$empty
    !for p=1 to $opkop
	term=($term)*(1/($over-$p+1))
    !next p
    GOED$n=$[factorial($opkop)*$term]    
    GG=$[(round($afrondingsfactor*$(GOED$n)))/$afrondingsfactor]
    !for p=1 to $opkop
	N=!item $p of $rangwoorden
	extratext=!append line de kans op de $N kaart is 1/$[$over-$p+1]<br> to $extratext
	berekening=!append line &times;1/$[$over-$p+1] to $berekening
    !next
    goed$n=Ik heb $[$k-$opkop] kaarten omgedraaid...er zitten nog $over kaarten in het pak<br>$extratext\
    <br>en dus is de kans $opkop ! $berekening = $(GOED$n) en afgerond $GG
    tex$n=0
 !exit
!endif

