!set n=$teller
bewerking=nivo/bewerking1.proc
somtekst$n=!record 14 of lang/remarks.$taal
nivo_title=!record 13 of lang/remarks.$taal
F=F\left(x\right)\,\,=\,\,
#functie=wisk functie
#som= latex som
#GOED= afgeleide
#goed= latex afggeleide

R=$graad
!if $graad=0
    R=$teller
!endif    
	
a=!randitem 2,3,4,5,6,7,-1,-2,-3,-4,-5,-6
b=!randitem 3,4,5,6,7,8,9,10,11,12   
c=!randitem 2,3,4,5,6,7,8,9,10,11,12
d=!randitem 1,2,3,4,5  
e=!randitem 2,3,4,5,6,7,8,9,10,11,12,13,14,15,16    
!if $b=$d
    b=$[$b+1]
!endif	
pm=!randitem +,-
mp=!randitem +,-
keuze=!randitem 1,2
!if $R = 1
    !if $keuze=1  
        GOED$n=$a*x^$b
    !else
        GOED$n=1/$b*x^$b
    !endif
    opgave$n=!exec pari printtex(deriv($(GOED$n),x))
    opgave$n=f(x)\,\,=\,\, $(opgave$n)
 !exit    
!endif

!if $R = 2 
    !if $keuze=1	
        GOED$n=$a*x^$b $pm $c*x 
    !else
        GOED$n=1/$b*x^$b $pm $c*x^2 
    !endif
    opgave$n=!exec pari printtex(deriv($(GOED$n),x))
    opgave$n=f(x)\,\,=\,\, $(opgave$n)
 !exit    
!endif

!if $R = 3
    d=$[$b+$d]
    !if $keuze=1
        GOED$n=$a*x^$d $pm $c*x^$b 
    !else
        GOED$n=$a*x^$d $pm 1/$b*x^$b 
    !endif
    opgave$n=!exec pari printtex(deriv($(GOED$n),x))
    opgave$n=f(x)\,\,=\,\, $(opgave$n)
 !exit    
!endif

!if $R > 3 
    GOED$n=$a*(x $pm $c)^$b $mp $e*x 
    opgave$n=f(x)\,\,=\,\, $[$a*$b] \cdot \left( x $pm $c \right)^{$[$b-1]} + $e 
 !exit    
!endif
